#----------------------------------------------------------------------------------------------------------
# Script de Sauvegarde 2.0 par Xania inspiré de celui de Sokobana
# 1) BACKUP_PATH doit indiquer le dossier de sauvegarde
# 2) Mortscript le dossier où se trouve Mortscript
# 3) Sav_list.txt doit contenir la liste des dossiers à sauvegarder et L le dossier où se trouve le fichier
# 4) STANDARD_MEMORY défini la part que vous réservez à la Storage Memory
#----------------------------------------------------------------------------------------------------------
MortScript = "\Storage Card\Program Files\MortScript-SP"
BACKUP_PATH = "\Storage Card\Backup"
L = "\Storage Card\Program Files\MortScript-SP\Sav_list.txt"
STANDARD_MEMORY = 5000
#-------------------------------------------------------------------------
BACKUP_MEMORY = 22000
SET SAVEREG, %MORTSCRIPT%&"\savereg.exe"
SET SETMEM, %MORTSCRIPT%&"\SetMem.exe"
Stmp = "\Temp"
# Nom des fichiers de sauvegardes
Set REGBACKUP, %BACKUP_PATH%&"\backup.rbk"
Set ZIPBACKUP, %BACKUP_PATH%&"\backup.zip"

# Agrandissement de la Storage Memory pour les gros ZIP
Run (%SETMEM%, "22000")

# Création du dossier backup
If (not DirExists (%BACKUP_PATH%))
	MkDir (%BACKUP_PATH%)
EndIf

sleep 300

# Création d'un dossier temporaire
If (not DirExists (%Stmp%))
	MkDir (%Stmp%)
EndIf

# Sauvegarde de la base de registre

If (fileExists(%REGBACKUP%))
	Rename(%REGBACKUP%,%REGBACKUP% & ".old",1)
EndIf
Run (%SAVEREG%,"s " & %REGBACKUP%)
Message( "Sauvegarde du registre terminée." )

# Sauvegarde des dossiers

freespace1 = 1
freespace2 = 2

ShowWaitCursor
Sleep 300
list = Readfile( L )
ForEach line in split %list%, "^LF^", 1
	If (line ne "")
		If (not DirExists(Stmp \ line))
			MkDir(Stmp \ line)
		EndIf
		ForEach zfile in files (line \ "*.*")
			If (not (FileAttribute(zfile,"system")||FileAttribute(zfile,"readonly")))
				If (not (zfile eq "Windows\MainShell.exe"))
					Copy (zfile, %Stmp% \ zfile, 1)
				EndIf
			EndIf
		EndForEach
		ZipFiles( Stmp \ line \ "*.*", Stmp \ "backup.zip", 1, line, 8 )
		Delete(Stmp \ line \ "*.*")
	EndIf
	While (%freespace1% <> %freespace2%)
		freespace1 = FreeDiskSpace("\")
		sleep 300
		freespace2 = FreeDiskSpace("\")
	EndWhile
EndForEach

If (fileExists(%ZIPBACKUP%))
	Rename(%ZIPBACKUP%,%ZIPBACKUP% & ".old",1)
EndIf
Rename (Stmp \ "backup.zip",ZIPBACKUP,1)
	ForEach line in split %list%, "^LF^", 1
		If (line ne "")
			DelTree(Stmp \ line \ "*.*")
		EndIf
	EndForEach

HideWaitCursor
Message( "Sauvegarde des dossiers terminée." )

# Positionnement de la Storage memory à la valeur utilisateur
Run (%SETMEM%, %STANDARD_MEMORY%)
Message ( "Sauvegarde terminée.")
Exit

#----------------------------------------------------------------------------------------------------------
# Script de Restauration 2.0 par Xania 
# 1) BACKUP_PATH doit indiquer le dossier de sauvegarde
# 2) Mortscript le dossier où se trouve Mortscript
# 3) Sav_list.txt doit contenir la liste des dossiers à restaurer et L le dossier où se trouve le fichier
# 4) STANDARD_MEMORY défini la part que vous réservez à la Storage Memory
#----------------------------------------------------------------------------------------------------------
MortScript = "\Storage Card\Program Files\MortScript-SP"
BACKUP_PATH = "\Storage Card\Backup"
L = "\Storage Card\Program Files\MortScript-SP\Sav_list.txt"
STANDARD_MEMORY = 5000
#-------------------------------------------------------------------------
BACKUP_MEMORY = 22000
SET SAVEREG, %MORTSCRIPT%&"\savereg.exe"
SET SETMEM, %MORTSCRIPT%&"\SetMem.exe"
Stmp = "\Temp"
# Nom des fichiers de sauvegardes
Set REGBACKUP, %BACKUP_PATH%&"\backup.rbk"
Set ZIPBACKUP, %BACKUP_PATH%&"\backup.zip"

If( question( "Vous avez fait un hard-reset!^NL^^NL^Voulez-vous restaurer?" ) )
	Call Restore
Else
	Message( "Restauration interrompue" )
EndIf
Exit

Sub Restore    

# Agrandissement de la Storage Memory pour les gros ZIP
Run (%SETMEM%, "22000")

If (fileExists(%ZIPBACKUP%))
	freespace1 = 1
	freespace2 = 2

# Restauration des Fichiers
	ErrorLevel("warn")
	UnzipAll(%ZIPBACKUP%,"\\")
	While (%freespace1% <> %freespace2%)
		freespace1 = FreeDiskSpace("\")
		sleep 300
		freespace2 = FreeDiskSpace("\")
	EndWhile
EndIf

# Restauration du registre

If (fileExists(%REGBACKUP%))
	Run (%SAVEREG%,"rxd " & %REGBACKUP%)
EndIf

# Positionnement de la Storage memory à la valeur utilisateur
Run (%SETMEM%, %STANDARD_MEMORY%)
Message ( "Restauration terminée.")

EndSub

quote:

---

Originally posted by xania

tu sauvegardes ce que tu veux mais \My Flash Disk étant de la mémoire flash, cela ne sert à rien de la sauvegarder par ce biais, tu peux néanmoins copier son contenu sur ton pc ou sur la sd card

je dis cela car chez moi dans \My Flash Disk il n'y a que gopal et poi-warner
les seuls fichiers interessants à sauvegarder sont les favoris de gopal (pf.cdb) et les contacts.

ceux qui installent des programmes en RAM peuvent aussi sauvegarder \Program Files

il peut y avoir aussi un interet à sauvegarder \My documents mais chez moi c'est vide

---

quote:

---

Originally posted by xania

Exact pour les deux fichiers manquants ! je les ai ajoutés dans le pack. Ces exe sont en fait l'autorun.exe de mortscript renommés ainsi.

---